**MACRO Functions**

Function FAME\_Payback(CashFlows, Optional Rate = 0)

'Calculate the payback period or discounted payback period

'Note that the first cash flow must be negative

Dim PayBack As Variant

Dim CumSum As Single

Dim CFCount, Counter As Integer

CFCount = CashFlows.Count 'Upper bound (i.e., number of cash flows)

CumSum = 0 'Cumulative sum of cash flows, stop when greater than 0

Counter = 0 'Counter variable

If Rate >= 1 Then Rate = Rate / 100

Do While CumSum <= 0 And Counter < CFCount

Counter = Counter + 1

CumSum = CumSum + CashFlows(Counter) / (1 + Rate) ^ (Counter - 1)

Loop

If CumSum >= 0 Then

CumSum = CumSum - CashFlows(Counter) / (1 + Rate) ^ (Counter - 1)

PayBack = (Counter - 2) - CumSum / (CashFlows(Counter) / (1 + Rate) ^ (Counter - 1))

FAME\_Payback = PayBack

Else

FAME\_Payback = "Payback > Life" 'Report error

End If

End Function

Function FAME\_Var(Values, Probabilities)

'Calculates the variance with unequal probabilities

Dim Variance As Variant

Dim Avg As Single

Dim Counter As Integer

If Probabilities.Count <> Values.Count Then 'If counts not equal, report error

Variance = "Counts not equal"

GoTo MacroEnd

End If

Variance = 0

Avg = FAME\_ExpValue(Values, Probabilities)

For Counter = 1 To Values.Count

Variance = Variance + (Values(Counter) - Avg) ^ 2 \* Probabilities(Counter)

Next Counter

MacroEnd:

FAME\_Var = Variance

End Function

Function FAME\_Covar(Values1, Values2, Probabilities)

'Calculates the covariance with unequal probabilities

Dim Covariance As Variant

Dim Avg1, Avg2 As Single

Dim Counter As Integer

If (Probabilities.Count <> Values1.Count) Or (Probabilities.Count <> Values2.Count) Then

Covariance = "Counts not equal"

GoTo MacroEnd

End If

Avg1 = FAME\_ExpValue(Values1, Probabilities)

Avg2 = FAME\_ExpValue(Values2, Probabilities)

For Counter = 1 To Values1.Count

Covariance = Covariance + (Values1(Counter) - Avg1) \* (Values2(Counter) - Avg2) \* Probabilities(Counter)

Next Counter

MacroEnd:

FAME\_Covar = Covariance

End Function

Function FAME\_Corr(Values1, Values2, Probabilities)

'Calculates the correlation with unequal probabilities

Dim Correlation As Variant

If (Probabilities.Count <> Values1.Count) Or (Probabilities.Count <> Values2.Count) Then

Correlation = "Counts not equal"

GoTo MacroEnd

End If

Correlation = FAME\_Covar(Values1, Values2, Probabilities) / (FAME\_StdDev(Values1, Probabilities) \* FAME\_StdDev(Values2, Probabilities))

MacroEnd:

FAME\_Corr = Correlation

End Function

Function FAME\_StdDev(Values, Probabilities)

'Calculates the standard deviation with unequal probabilities

Dim StdDeviation As Variant

If Probabilities.Count <> Values.Count Then

StdDeviation = "Counts not equal"

GoTo MacroEnd

End If

StdDeviation = FAME\_Var(Values, Probabilities)

MacroEnd:

If IsNumeric(StdDeviation) Then

FAME\_StdDev = Sqr(StdDeviation)

Else

FAME\_StdDev = StdDeviation

End If

End Function

Function FAME\_CV(Values, Probabilities)

'Calculates the coefficient of variation with unequal probabilities

Dim CoefVariation As Variant

If Probabilities.Count <> Values.Count Then

CoefVariation = "Counts not equal"

GoTo MacroEnd

End If

CoefVariation = 0

CoefVariation = FAME\_StdDev(Values, Probabilities) / FAME\_ExpValue(Values, Probabilities)

MacroEnd:

FAME\_CV = CoefVariation

End Function

Function FAME\_ExpValue(Values, Probabilities)

'Calculates the expected value with unequal probabilities

Dim ExpValue As Variant

Dim i As Integer

If Probabilities.Count <> Values.Count Then

ExpValue = "Counts not equal"

GoTo MacroEnd

End If

ExpValue = 0

For i = 1 To Values.Count

ExpValue = ExpValue + Values(i) \* Probabilities(i)

Next i

MacroEnd:

FAME\_ExpValue = ExpValue

End Function